home *** CD-ROM | disk | FTP | other *** search
/ Die Ultimative Software-P…i Collection 1996 & 1997 / Die Ultimative Software-Pakete CD-ROM fur Atari Collection 1996 & 1997.iso / a / a_funk / geograph.tos / GEOGRAPH / QTHSHARP.TXT < prev   
Encoding:
Text File  |  1994-05-08  |  9.0 KB  |  212 lines
  1. SHARP @DL        de:DG4HAB 18.01.94 13:00  60   9518 Bytes
  2. QTH-Loc. Prg. (1260/61/62)
  3. *** Bulletin-ID: 171411DB0GR ***
  4.  
  5. 940118/1255z DB0RBS, 940118/1236z DB0ROT, 940118/1144z DB0AIS
  6. 940118/1141z DB0SIF, 940118/1143z DB0SON, 940118/1135z DB0FP
  7. 940118/1131z DB0ERF, 940118/1120z DB0BBX, 940118/1115z DB0JES
  8. 940117/1545z DB0GR
  9. de DG4HAB @ DB0GR.DEU.EU
  10. to SHARP @ DL
  11.  
  12. de: DG4HAB @ DB0GR Joerg AUBi 45
  13. to: DB0GR (SHARP) @ DL
  14.  
  15. +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  16. +  Arbeitsgemeinschaft UKW Berlin, AUB Genfer Str. 109, 13407 Berlin  +
  17. +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  18.                                                              12.01.1994
  19.  
  20.     Kleines Basic-Programm zur Errechnung der Antennenrichtung und
  21.     Entfernung zwischen zwei Amateurfunklokatorangaben
  22.  
  23. Moin, moin all tosammen!
  24.  
  25. Waehrend meiner Vorbereitung zur Amateurfunklizenz stiess ich, wie wohl
  26. jeder in dieser Situation, auf den Amateurfunklokator. Fuer mich, der
  27. sich schon laengere Zeit mit Navigation beschaeftigt, erhob sich nun die
  28. Frage:
  29.  
  30.    "Wozu haben die Amateurfunker ein anderes weltweites Koordinatensystem
  31.     geschaffen und dabei gegenueber dem in der Seefahrt bekannten Ko-
  32.     ordinatensystem eine Vergroeberung des Rasters vorgenommen?"
  33.  
  34. Inzwischen habe ich mir eine Antwort auf diese Frage zurechtgelegt, die
  35. mir einleuchtet und ich hier zum Besten geben moechte:
  36.  
  37. Sieht man sich einmal die Positionsangabe eines Schiffes an und ver-
  38. gleicht dieselbe Position mit Hilfe des  Amateurfunklokators, so er-
  39. kennt man sofort den Vorteil der wenigen Zeichen, die notwendig  sind.
  40. Besonders die Telegraphisten werden diesen Vorteil zu schaetzen wissen.
  41. Aber auch in anderen Betriebsarten hat diese Ortsangabe ihre Vorteile.
  42. Wenn zwei Buchstaben, zwei Ziffern und nochmals zwei Buchstaben aufge-
  43. nommen wurden, kann es sich nur um den QTH-Lokator gehandelt haben.
  44. Durch die besonders kurz gehaltene Angabe reicht es mit grosser Wahr-
  45. scheinlichkeit, den Standort zwischen zwei Fadingeinbruechen mitzu-
  46. teilen. Fuer diesen Vorteil kann man auch die geringfuegige Ungenauig-
  47. keit in Kauf nehmen.
  48.  
  49. Seefahrt:                             Amateurfunk:
  50. ---------                             ------------
  51. 52 Grad 30,81'Nord     gegenueber     JO62OM
  52. 13 Grad 14,50'Ost
  53.  
  54. Der Amateurfunklokator ist gegenueber dem in der Seefahrt verwandten
  55. Koordinatensystem groeber und hat einen anderen Ursprungspunkt.
  56. Waehrend man noerdliche und suedliche Breiten unterscheidet und die
  57. Laengengrade vom willkuerlich nach Greenwich gelegten 0. Laengengrad
  58. aus angibt, so hat der Amateurfunklokator seinen Ursprung am Suedpol
  59. bei 180 Grad westlicher Laenge. Hier liegt das Lokatorfeld  AA00AA.
  60. Das letzte und damit die hoechstmoegliche Angabe des Amateurfunklokator
  61. heisst: RR99XX.
  62.  
  63. Um mich in diesen fuer mich zu dem Zeitpunkt ungewoehnlichen
  64. Koordinatensystem zurecht zufinden, musste ich mich damit beschaeftigen
  65. und was bietet sich da besser an als ein Programm in diesem Zusammenhang
  66. zu schreiben? Damit das Programm ueberall, also auch mal beim Fieldday
  67. zum Einsatz kommen kann, sollte es in den schon vorhandenen programmier-
  68. baren Taschenrechner Sharp 1262 hineinpassen. Das Ergebniss zeigen die
  69. folgenden Listings:
  70.  
  71. Listing 1
  72. (in allgemein verstaendlichem Basic, mit eingestreuten Erlaeuterungen,
  73.  damit es in jeden Basicdialekt umgeschrieben werden kann)
  74.  
  75. 4000 REM AFUNKNAV
  76.      REM Eventuell muessen hier die Variablen deklariert werden dazu
  77.      REM kann die Variablenliste im Anschluss eine grosse Hilfe sein.
  78. 4005 PI = 3.141592654
  79. 4006 GOTO 4010
  80.      REM Unterprogramm zur Sicherstellung, das keine Antennenrichtung von
  81.      REM mehr als 360 Grad ensteht
  82. 4007 K = (K+360)/360
  83.      K = (K-INT(K))*360
  84.      RETURN
  85.      REM Breite wird aus den Lokatorangaben extrahiert und berechnet
  86.      REM Der Befehl ASC gibt den ASCII-Wert des jeweiligen Zeichens an.
  87.      REM Hier muessen Grossbuchstaben verwandt werden.
  88. 4008 B = (ASC(MID$(C$,2,1))-65)*10- 90+
  89.          (ASC(MID$(C$,4,1))-48)+
  90.         ((ASC(MID$(C$,6,1))-65)/24)
  91.      RETURN
  92.      REM Laenge wird aus den Lokatorangaben extrahiert und berechnet
  93. 4009 L = (ASC(MID$(C$,1,1))-65)*20-180+
  94.          (ASC(MID$(C$,3,1))-48)* 2+
  95.         ((ASC(MID$(C$,5,1))-65)/12)
  96.      RETURN
  97.      REM Hier beginnt das Hauptprogramm
  98.      REM mit der Eingabe RUN 4010 kann gestartet werden
  99. 4010 CLS
  100.      PRINT "Amateurfunk-Locator >> Kurs + Distanz"
  101.      INPUT "Locator1: ";A$
  102.      REM Bildschirm loeschen, Ueberschrift und Abfrage des ersten Lokators
  103.      REM Uebergabe der Daten an die Unterprogramme und Aufruf derselben
  104.      C$ = A$
  105. 4020 GOSUB 4008
  106.      B1 = B
  107.      GOSUB 4009
  108.      L1 = L
  109.      REM Positionieren der Abfrage des zweiten Lokators
  110.      REM hier auf die zweite Zeile
  111.      CURSOR 24
  112.      INPUT "Locator2: ";BB$
  113.      REM Uebergabe der Daten an die Unterprogramme und Aufruf derselben
  114.      C$ = BB$
  115.      GOSUB 4008
  116.      B2 = B
  117.      GOSUB 4009
  118.      L2 = L
  119.      REM Jetzt stehen die Daten fuer B1, B2, L1 und L2 fest
  120.      REM Bildung der Differenz von Breite1 und Breite2.
  121.      REM Zur Vermeidung einer Division durch Null wird die Breite2
  122.      REM leicht veraendert.
  123. 4030 G = B2-B1
  124.        IF G=0 THEN  LET B2=B2+.00001
  125.      REM Berechnung der Antennenrichtung oder Kurses.
  126.      REM Bei der Uebertragung auf einen anderen Rechner ist zu Beachten,
  127.      REM das hier im Bogenmass gerechnet wird.
  128.      REM Umrechnung ins Bogenmass
  129. 4035 L1 = L1*PI/180
  130.      L2 = L2*PI/180
  131.      B1 = B1*PI/180
  132.      B2 = B2*PI/180
  133. 4040 K = 180+(ATN(((L2-L1)*COS((B2+B1)/2))/(B2-B1)))*180/PI
  134.      REM Mit diesem Unterprogramm wird sichergestellt, das keine
  135.      REM Antennenrichtungen groesser als 360 Grad entstehen.
  136.      GOSUB 4007
  137.      REM Berechnung der Distanz
  138. 4050 D = ((B2-B1)*180*60)/(COS(K*PI/180)*PI)
  139.          IF D<0 THEN  LET K=K+180
  140.      REM Mit diesem Unterprogramm wird sichergestellt, das keine
  141.      REM Antennenrichtungen groesser als 360 Grad entstehen.
  142.     GOSUB 4007
  143.      REM Bildschirm loeschen und formatierte Anzeige der beteiligten
  144.      REM Lokatoren und der Antennenrichtung und Entfernung.
  145. 4060 CLS
  146.      USING "######.#"
  147.      PRINT A$;"  Peilung:";K
  148.      REM Da die Formeln das Ergebnis in Seemeilen ausgeben erfolgt hier
  149.      REM die Umrechnung in Kilometer
  150.      PRINT BB$;" Entfernung/km:";(ABS D)*1.852
  151.      END
  152.  
  153.  
  154. Variablen und ihre Verwendung: (gilt fuer die allgemeine und die Sharp-
  155.                                 spezifische Version des Listings)
  156.  
  157. A$  - Stringvariable      - zur Aufnahme von Lok. 1
  158. BB$ - Stringvariable      - zur Aufnahme von Lok. 2
  159. C$  - Stringvariable      - zur Uebergabe beider Lok. an die Unterprog.
  160. B   - numerische Variable - Breite allgemein vom Unterprogramm
  161. B1  - numerische Variable - Breite des ersten Lok.
  162. B2  - numerische Variable - Breite des zweiten Lok.
  163. L   - numerische Variable - Laenge allgemein vom Unterprogramm
  164. L1  - numerische Variable - Laenge des ersten Lok.
  165. L2  - numerische Variable - Laenge des zweiten Lok.
  166. G   - numerische Variable - Differenz in der Breite
  167. D   - numerische Variable - Distanz zwischen Lok. 1 + Lok. 2 in Seemeilen
  168. K   - numerische Variable - Kurs bzw. Richtung von Lok. 1 zu Lok. 2
  169.  
  170.  
  171.  
  172. Listing 2 (speziell fuer Anwender der programmierbaren Taschenrechner
  173.            aus der Baureihe Sharp PC-1260/61/62)
  174.  
  175. 4000 REM AFUNKNAV
  176. 4007 K=K+360)/360:K=(K- INT K)*360: RETURN
  177. 4008 B=( ASC ( MID$ (C$,2,1))-65)*10-90+( ASC ( MID$ (C$,4,1))-48)
  178.        +(( ASC ( MID$ (C$,6,1))-65)/24): RETURN
  179. 4009 L=( ASC ( MID$ (C$,1,1))-65)*20-180+( ASC ( MID$ (C$,3,1))-48)*2
  180.        +(( ASC ( MID$ (C$,5,1))-65)/12): RETURN
  181. 4010 "=": CLS : PRINT "Amateurfunk-Locator     >> Kurs + Distanz"
  182.      : INPUT "Locator1: ";A$:C$=A$
  183. 4020 GOSUB 4008:B1=B: GOSUB 4009:L1=L: CURSOR 24
  184.      : INPUT"Locator2:";BB$:C$=BB$ : GOSUB 4008:B2=B: GOSUB 4009:L2=L
  185. 4030 G=B2-B1: IF G=0 THEN  LET B2=B2+.00001
  186. 4040 K= ATN (( π *(L2-L1))/(180*(( LN ( TAN (45+B2/2)))
  187.         -( LN( TAN (45+B1/2)))))): GOSUB 4007
  188. 4050 D=(60*(B2-B1))/( COS K): IF D<0 THEN  LET K=K+180: GOSUB 4007
  189. 4060 CLS : WAIT 0: USING "######.#": PRINT A$;"  Peilung:";K: WAIT
  190.      : CURSOR 24 : PRINT BB$;" Entf./km:";( ABS D)*1.852: END
  191.  
  192. Nach der  langweiligsten Sache der Welt, dem Abtippen von Listings
  193. nun zur Anwendung:
  194.  
  195. Nach dem Druecken der Tasten "DEF" und "=" erscheint eine Ueberschrift,
  196. die mit "ENTER" erlischt und nach dem ersten Lokator fragt. Die Eingabe
  197. wird mit "ENTER" bestaetigt und es wird nach dem zweiten Lokator ge-
  198. fragt. Auch diesen gibt man mit nachfolgendem "ENTER" ein und die
  199. Rechnerei geht los. Nach wenigen Sekunden stehen am Anfang der Zeilen
  200. untereinander die beiden eingegebenen Lokator und rechts daneben die
  201. Entfernung und die Richtung vom ersten zum zweiten Lokatorpunkt.
  202.  
  203. Ueber Erfahrungen oder auch Kritik wuerde ich mich sehr freuen und nehme
  204. sie gern hier in der Box DB0GR in der Rubrik AUB oder unter meinem
  205. Rufzeichen entgegen.
  206.  
  207. Viel Spass beim Probieren und Rechnen mit dem Programm!
  208.  
  209.                           73 de Joerg DG4HAB @ DB0GR AUBi45
  210.  
  211.  
  212.